EXCEL FEED: Re: [SPAM] ]] XL-mania [[ Menentukan Nilai Maximum

Selasa, 28 Januari 2020

Re: [SPAM] ]] XL-mania [[ Menentukan Nilai Maximum

Terimakasih Banyak atas penjabarannya Mr.Kid....
Njenengan Terbaiek

Pada Selasa, 28 Januari 2020 17.05.34 WIB, 'Mr. Kid' mr.nmkid@gmail.com [XL-mania] <xl-mania@yahoogroups.com> menulis:

larik (array) hasil sum yang bergerak seperti SUM($D2:D2) , SUM($D2:E2) , dst bisa diperoleh dengan cara mengalikan array data (matriks data 1 x N) dengan array segitiga atas bernilai 1 (N x N)

array data (matriks 1 x N) : d2:j2

array segitiga atas bernilai 1 (matriks N x N) : (column($d$1:$j$1)>=Transpose(column($d$1:$j$1)))*1

perkalian matriksnya : =mmult( d2:j2 , (column($d$1:$j$1)>=Transpose(column($d$1:$j$1)))*1 )

dari hasil larik SUM($D2:D2) , SUM($D2:E2) , dst yang disusun dengan perkalian matriks, akan dicari yang memenuhi nilai P persen dari total

total : =sum(d2:j2)

P persen total (misal P=95%): =0.95*sum(d2:j2)

dikatakan memenuhi jika setiap nilai (item) dalam larik hasil sum [hasil perkalian matriks] adalah >= nilai P persen total

=mmult( d2:j2 , (column($d$1:$j$1)>=Transpose(column($d$1:$j$1)))*1 ) >= 0.95*sum(d2:j2)

hasilnya larik true atau false

supaya mudah dikalkulasi, true diubah jadi 1, dan false diubah jadi 0, menjadi :

=1* ( mmult( d2:j2 , (column($d$1:$j$1)>=Transpose(column($d$1:$j$1)))*1 ) >= 0.95*sum(d2:j2) )

didapat larik berisi 1 atau 0, mulai dari 0 untuk yang tidak memenuhi dan 1 untuk yang memenuhi secara berurutan dari hasil larik sum terendah ke tertinggi

yang dicari adalah yang memenuhi pertama, berarti yang bernilai 1 yang pertama kali ditemukan.

=Match( 1 , 1* ( mmult( d2:j2 , (column($d$1:$j$1)>=Transpose(column($d$1:$j$1)))*1 ) >= 0.95*sum(d2:j2) ) , 0 )

hasilnya adalah lokasi item pertama yang memenuhi

hasil lokasi ini digunakan untuk mengambil nilai yang dibutuhkan dari d1:j1

=Index( $d$1:$j$1 , Match( 1 , 1* ( mmult( d2:j2 , (column($d$1:$j$1)>=Transpose(column($d$1:$j$1)))*1 ) >= 0.95*sum(d2:j2) ) , 0 ) )

karena prosesnya melibatkan komputasi array, maka formula di-entry sebagai array formula (tekan CTRL SHIFT ENTER) menggantikan penekanan ENTER umumnya

On Tue, Jan 28, 2020 at 3:26 PM nurul_kurnia05@yahoo.co.id [XL-mania] <XL-mania@yahoogroups.com> wrote:

Terimakasih Kakak.... iya selama ini saya mengunkana manual dg IF sum, akan tetapai IF sum hanya berlaku hingga header ke -11 saja. nah bagaimana jika Headernya 30 an.

Pada Selasa, 28 Januari 2020 14.44.08 WIB, Raden Saputra raden.saputra@gmail.com [XL-mania] <xl-mania@yahoogroups.com> menulis:

Dear nurul_kurnia05@yahoo.co.id,

coba formula : "=IF(SUM($D2:D2)>=95;"0,01";IF(SUM($D2:E2)>=95;"0,03";IF(SUM($D2:F2)>=95;"0,05";IF(SUM($D2:G2)>=95;"0,07";IF(SUM($D2:H2)>=95;"0,85";IF(SUM($D2:I2)>=95;"0,87";IF(SUM($D2:J2)>=95;"0,89";"")))))))"

Regards

Raden

On Tue, Jan 28, 2020 at 10:36 AM nurul_kurnia05@yahoo.co.id [XL-mania] <XL-mania@yahoogroups.com> wrote:

Mohon maaf sebelumnya, karena infonya tidak detail, pada intinya saya hendak mencari jumlah dari Header D1 Ke Header J1 yang jumlahnya minimal >=95.

Misalkan :

ADI => sum (D2: J2) yang >= 95 , ternyata ada di Header 0.03 (E1)

Pada Intinya mencari jumlah maximum >=95 ada di header mana.

Pada Jumat, 24 Januari 2020 15.05.51 WIB, Idrus, Adi <adi.idrus@bridgestone.com> menulis:

Ini maksudnya gimana ya bu? bisa diperjelas kah

From: XL-mania@yahoogroups.com [mailto:XL-mania@yahoogroups.com]
Sent: Friday, January 24, 2020 10:35 AM
To: XL-mania@yahoogroups..com
Subject: [SPAM] ]] XL-mania [[ Menentukan Nilai Maximum [1 Attachment]

Sahabat XL Mania,

saya ada kendala mengenai penggunaan nilai maximum di XL, mohon di bantu bagamana cara menetukan nilai Maximum, jika menggunakan IF(sum) akan ada limited di kolom 11

terimakasih atas bantuannya

--
Raden Saputra

__._,_.___

Posted by: nurul_kurnia05@yahoo.co.id

Reply via web post

•

Reply to sender

•

Reply to group

•

Start a New Topic

•

Messages in this topic (6)

Check out the automatic photo album with 1 photo(s) from this topic.

:: XL-mania ::::::::::::::::::::
Momods sekarang jualan tas di www.flirtypoodle.com ha ha ha....
:: ------------- ::::::::::::::::::::
DILARANG : MLM, money game, OOT, iklan tanpa izin, SARA, testing, pembicaraan pribadi, one line message, melecehkan, tidak sopan.
:: ------------- ::::::::::::::::::::
Buat subjek yang kreatif, jangan : "tanya", "help", "mohon bantu"
Usahakan besar attachment < 200 kb. Gunakan winzip jika perlu.
:: ------------- ::::::::::::::::::::
Ajak teman-teman Anda bergabung dengan mengirim e-mail kosong ke
XL-mania-subscribe@yahoogroups.com atau kirimkan mereka file dari
http://groups.yahoo.com/group/XL-mania/files/Promotion/
:: ------------- ::::::::::::::::::::
Berikan testimoni di :
http://www.xl-mania.com/2008/06/testimoni-xl-mania.html
:: ------------- ::::::::::::::::::::
Message lama ada di :
http://groups.yahoo.com/group/XL-mania/messages [perlu yahoo id]
http://www.mail-archive.com/xl-mania@yahoogroups.com

Visit Your Group